การใช้งาน wemod d1 สั่งงาน on off led ผ่าน network wifi

วันนีเอารถยนต์เข้าศูนย์ตามระยะ ระหว่างรอว่างๆ เลยเขียนบทความง่าย ๆ สั่งงาน led ผ่านเน็ต

สำหรับ wemod d1 บอร์ดที่ใช้ชิฟ esp8266 รองรับไวไฟ

โดยเราต้องการสั่งเปิด-ปิด หลอด led ที่อยู่บนบอร์ด wemod d1 ได้ง่ายๆ

โดยทำให้ wemod d1 เป็น web server ซึ่งเราจะใช้ web brower ในการ requst url

ให้ led เปลี่ยนสถานะ

เริ่มที่โปรแกรม Arduino ide สามารถอัพโหลดลงได้เลยนะครับ ดังนี้

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>

const int RELAY_PIN = 2; //RELAY
 
const char* ssid = "MITSU-RAYONG-K";
const char* password = "msrayong";
MDNSResponder mdns;
ESP8266WebServer server(80);

void handleRoot() {
  server.send(200, "text/plain", "hello from esp8266!");
}

void handleNotFound(){
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET)?"GET":"POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i=0; i<server.args(); i++){
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
}
 
void setup(void){
  pinMode(RELAY_PIN, OUTPUT);
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    digitalWrite(RELAY_PIN, 1);
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  digitalWrite(RELAY_PIN, 0);
 
  if (mdns.begin("esp8266", WiFi.localIP())) {
    Serial.println("MDNS responder started");
  }
 
  server.on("/", handleRoot);
 
  server.on("/lightsON", [](){
  server.send(200, "text/plain", "Okay -- Light is ON!");
  digitalWrite(RELAY_PIN, 0);
  });
 
  server.on("/lightsOFF", [](){
  server.send(200, "text/plain", "Okay -- Light is OFF!");
  digitalWrite(RELAY_PIN, 1);
  });

  server.onNotFound(handleNotFound);
 
  server.begin();
  Serial.println("HTTP server started");
}
 
void loop(void){
  server.handleClient();
}

จากนั้นตรวจสอบผ่าน serial port เพื่อตรวจสอบ ip ของ web server ตามรูปด้านล่าง

ผลทดสอบ ดูที่บอร์ด wemod d1 นะครับ

หลังจากนั้นเปลี่ยน url ไหม่เป็น /lightsOFF

ผลทดสอบ ดูที่บอร์ด wemod d1 นะครับ